Merge branch 'mr/jicquel/#53.rename_and_move' into 'master'

Preserve trailing directory separator with Rename_And_Move

See merge request eng/toolchain/gnatcoll-core!99

Author: Jicquel

src/projects/gnatcoll-projects-normalize.adb

@@ -2934,9 +2934,29 @@ package body GNATCOLL.Projects.Normalize is
                               Get_Host (New_Dir));
                begin
                   if not Is_Absolute_Path (D) then
-                     Set_String_Value_Of
-                       (Node, Tree_Node,
-                        Get_String (+Relative_Path (File, New_Dir)));
+                     declare
+                        Dir_String : constant String := String (D);
+
+                        --  Get whether string ends with a directory separator
+
+                        Ends_With_Separator : constant Boolean :=
+                          Dir_String (Dir_String'Last) = '/' or else
+                          Dir_String (Dir_String'Last) = '\';
+
+                        --  If it does, make sure that it is kept, as it
+                        --  would be removed by Normalize_Pathname.
+
+                        Suffix : constant String :=
+                                   (if Ends_With_Separator then
+                                      "" & Dir_String (Dir_String'Last)
+                                    else
+                                      "");
+                     begin
+                        Set_String_Value_Of
+                           (Node, Tree_Node,
+                            Get_String
+                              (+Relative_Path (File, New_Dir) & Suffix));
+                     end;
                   end if;
                end;
 

testsuite/tests/projects/rename_and_move/foobar_p.gpr

@@ -0,0 +1,8 @@
+project Foobar_P is
+
+   for Exec_Dir use ".";
+   for Source_Dirs use ("src/" & "subsrc/");
+   for Main use ("main.adb");
+
+end Foobar_P;
+

testsuite/tests/projects/rename_and_move/p.gpr

@@ -0,0 +1,5 @@
+project P is
+   for Exec_Dir use ".";
+   for Source_Dirs use ("src/" & "subsrc/");
+   for Main use ("main.adb");
+end P;

testsuite/tests/projects/rename_and_move/prj.gpr

@@ -0,0 +1,7 @@
+with "gnatcoll";
+
+project Prj is
+   for Exec_Dir use ".";
+   for Source_Dirs use (".", "src/" & "subsrc/");
+   for Main use ("test.adb");
+end Prj;

testsuite/tests/projects/rename_and_move/src/subsrc/main.adb

@@ -0,0 +1,4 @@
+function Main return Integer is
+begin
+  return 0;
+end Main;

testsuite/tests/projects/rename_and_move/test.adb

@@ -0,0 +1,63 @@
+with GNATCOLL.Projects; use GNATCOLL.Projects;
+with GNATCOLL.VFS;      use GNATCOLL.VFS;
+with Test_Assert;       use Test_Assert;
+with Ada.Directories;
+with Ada.Direct_IO;
+with Ada.Strings.Fixed; use Ada.Strings.Fixed;
+
+function Test return Integer is
+   Tree      : Project_Tree;
+   Proj_File : constant String := "p.gpr";
+   Proj      : Project_Type;
+   Dummy     : Boolean;
+
+   function Read_File (File_Name : String) return String;
+   --  Read a file and return its content as a String
+
+   function Read_File (File_Name : String) return String
+   is
+      File_Size : constant Natural :=
+                    Natural (Ada.Directories.Size (File_Name));
+
+      subtype File_String    is String (1 .. File_Size);
+      package File_String_IO is new Ada.Direct_IO (File_String);
+
+      File     : File_String_IO.File_Type;
+      Contents : File_String;
+
+   begin
+      File_String_IO.Open  (File, Mode => File_String_IO.In_File,
+                                  Name => File_Name);
+      File_String_IO.Read  (File, Item => Contents);
+      File_String_IO.Close (File);
+
+      return String (Contents);
+   end Read_File;
+
+begin
+   Tree.Load (Create (Filesystem_String (Proj_File)));
+
+   Proj := Tree.Root_Project;
+   Proj.Rename_And_Move
+      ("foobar_" & Proj.Name, Create
+        (Filesystem_String
+          (Ada.Directories.Containing_Directory
+            (+Proj.Project_Path.Full_Name))));
+
+   Tree.Recompute_View;
+   Dummy := Proj.Save;
+
+   declare
+      Content : constant String := Read_File ("foobar_" & Proj_File);
+   begin
+      --  Check that the separator are not removed
+
+      Assert (Index (Content, """src/"" & ""subsrc/""") > 0);
+
+      --  Check that the project name has been updated
+
+      Assert (Index (Content, "Foobar_P") > 0);
+   end;
+
+   return Report;
+end Test;

testsuite/tests/projects/rename_and_move/test.yaml

@@ -0,0 +1,8 @@
+description: Test Rename_And_Move and ensure that trailing directory separator are kept
+data:
+    - "p.gpr"
+    - "prj.gpr"
+    - "test.adb"
+    - "src"
+    - "src/subsrc"
+    - "src/subsrc/main.adb"