Add FindPythonPackage and use it to detect memap dependencies

Author: multiplemonomials

CMakeLists.txt

@@ -198,7 +198,6 @@ endfunction()
 # Parse toolchain generated map file of `target` and display a readable table format.
 #
 function(mbed_generate_map_file target)
-     find_package (Python3)
      add_custom_command(
          TARGET
              ${target}
@@ -234,7 +233,10 @@ endfunction()
 function(mbed_set_post_build target)
     mbed_validate_application_profile(${target})
     mbed_generate_bin_hex(${target})
-    mbed_generate_map_file(${target})
+
+    if(HAVE_MEMAP_DEPS)
+        mbed_generate_map_file(${target})
+    endif()
 endfunction()
 
 # Ninja requires to be forced for response files

tools/cmake/CheckPythonPackage.cmake

@@ -0,0 +1,69 @@
+# Copyright (c) 2020 ARM Limited. All rights reserved.
+# SPDX-License-Identifier: Apache-2.0
+
+# CMake functions for checking for Python packages
+# Requires PYTHON_EXECUTABLE to be defined.  Call FindPythonInterp first!
+
+# NOTE: if moving this file, be sure to also move python_packagecheck.py
+
+# must evaluate this now since CMAKE_CURRENT_LIST_DIR doesn't work in function scope
+set(PYTHON_PACKAGECHECK_SCRIPT ${CMAKE_CURRENT_LIST_DIR}/python_packagecheck.py)
+
+# set OUTPUT_VAR to whether PACKAGENAME was found
+function(check_python_package PACKAGENAME OUTPUT_VAR)
+
+    # can't have Python packages without Python!
+    if(NOT Python3_FOUND)
+        set(${OUTPUT_VAR} FALSE PARENT_SCOPE)
+        return()
+    endif()
+
+    set(NEED_TO_RUN_CHECK TRUE)
+
+    if(DEFINED ${OUTPUT_VAR})
+        if(${OUTPUT_VAR})
+
+            # if the python interpreter changed, we need to recheck
+            if("${PY_INTERP_FOR_${OUTPUT_VAR}}" STREQUAL "${Python3_EXECUTABLE}")
+                set(NEED_TO_RUN_CHECK FALSE)
+            endif()
+
+        endif()
+    endif()
+
+    if(NEED_TO_RUN_CHECK)
+        set(PY_INTERP_FOR_${OUTPUT_VAR} ${Python3_EXECUTABLE} CACHE INTERNAL "The python interpreter used to run the ${OUTPUT_VAR} check" FORCE)
+
+        execute_process(COMMAND ${Python3_EXECUTABLE} ${PYTHON_PACKAGECHECK_SCRIPT} ${PACKAGENAME}
+                RESULT_VARIABLE PACKAGECHECK_RESULT)
+
+        if(${PACKAGECHECK_RESULT} EQUAL 0)
+            set(HAVE_PACKAGE TRUE)
+        else()
+            set(HAVE_PACKAGE FALSE)
+        endif()
+
+            if(HAVE_PACKAGE)
+            message(STATUS "Checking for Python package ${PACKAGENAME} -- found")
+        else()
+            message(STATUS "Checking for Python package ${PACKAGENAME} -- not found")
+        endif()
+
+        set(${OUTPUT_VAR} ${HAVE_PACKAGE} CACHE BOOL "Whether the Python package ${PACKAGENAME} was found" FORCE)
+        mark_as_advanced(${OUTPUT_VAR})
+
+    endif()
+endfunction(check_python_package)
+
+# check that PACKAGENAME can be imported, and print an error if not
+function(verify_python_package PACKAGENAME)
+
+    # we can just generate our own variable name
+    string(TOUPPER "HAVE_${PACKAGENAME}" HAVE_VAR_NAME)
+
+    check_python_package(${PACKAGENAME} ${HAVE_VAR_NAME})
+
+    if(NOT ${HAVE_VAR_NAME})
+        message(FATAL_ERROR "The required Python package ${PACKAGENAME} was not found in ${Python3_EXECUTABLE}.  Please install it.")
+    endif()
+endfunction(verify_python_package)

tools/cmake/app.cmake

@@ -23,3 +23,16 @@ enable_language(C CXX ASM)
 # set executable suffix (has to be done after enabling languages)
 # Note: This is nice to have, but is also required because STM32Cube will only work on files with a .elf extension
 set(CMAKE_EXECUTABLE_SUFFIX .elf)
+
+# Find Python and needed packages
+find_package(Python3)
+include(${CMAKE_CURRENT_LIST_DIR}/CheckPythonPackage.cmake)
+check_python_package(intelhex HAVE_INTELHEX)
+check_python_package(prettytable HAVE_PRETTYTABLE)
+
+if(Python3_FOUND AND HAVE_INTELHEX AND HAVE_PRETTYTABLE)
+	set(HAVE_MEMAP_DEPS TRUE)
+else()
+	set(HAVE_MEMAP_DEPS FALSE)
+	message(STATUS "Missing Python dependencies (python3, intelhex, prettytable) so the memory map cannot be printed")
+endif()

tools/cmake/python_packagecheck.py

@@ -0,0 +1,16 @@
+"""
+mbed SDK
+Copyright (c) 2020 ARM Limited
+SPDX-License-Identifier: Apache-2.0
+"""
+
+#file which is invoked by the cmake build system to check if all necessary python packages are installed.
+
+import sys
+
+try:
+    __import__(sys.argv[1])
+except ImportError:
+    exit(1)
+
+exit(0)